OpenEuphoria

1. EuSQLite

• Posted by Juergen Luethje <j.lue at gmx.de> Jun 08, 2007
• 635 views
• Last edited Jun 09, 2007

Hi Chris,

out of curiosity, I just downloaded your file "eusqlite.zip".
At the first glance, I stumbled across the function peek_sequence().
Below there are some other functions which might be faster.
I don't know whether that really matter, though.

Regards,
   Juergen

------------------------------------------------------------------------

global function peek_sequence (atom addr, integer len)
   integer i, tmp
   sequence seq

   seq=""
   i=0
   tmp=peek(addr)
   while (tmp != 0 and i<len) do
      seq = append(seq, tmp)
      i = i + 1
      tmp = peek(addr+i)
   end while

   return seq
end function

--======================================================================

global function peek_sequence1 (atom addr, integer len)
   integer i, tmp
   sequence seq

   seq = repeat(0, len)
   i = 0
   tmp = peek(addr)
   while tmp != 0 and i < len do
      i += 1
      seq[i] = tmp
      tmp = peek(addr+i)
   end while

   return seq[1..i]
end function

------------------------------------------------------------------------

global function peek_sequence2 (atom addr, integer len)
   integer i
   sequence seq

   seq = peek({addr, len})
   i = find(0, seq) - 1
   if i = -1 then
      i = len
   end if

   return seq[1..i]
end function

------------------------------------------------------------------------

atom Kernel32
integer Lstrlen

if platform() = WIN32 then
   Kernel32 = open_dll("kernel32.dll")
   Lstrlen  = define_c_func(Kernel32, "lstrlenA", {C_POINTER}, C_ULONG)
end if

global function peek_sequence3 (atom addr, integer len)
   integer i

   i = c_func(Lstrlen, {addr})
   if i > len then
      i = len
   end if

   return peek({addr, len})
end function

------------------------------------------------------------------------

3. Re: EuSQLite

• Posted by Jesus Consuegra <jconsuegra at yahoo.com> Jun 09, 2007
• 616 views

Hi Juergen!
I'm using heavily EuSqlite3, so I'm interested in any optimization that can be
done...
I've been taking a glimpse to your changes, and what I see is that in
"peek_sequence2" you replaced

seq = ""    by    seq = repeat(0, len)

and

return seq  by    return seq[1..i]

Would this mean a big difference?

Because if so, I should adapt it yet. I'm writing a web page generator for a
friend that does historical investigation. He puts all the information inside big
text files, where we've agreed a set of markers to identify titles, actors,
references and document text. Document text can be quite big and is stored inside
a sequence....
What I do is to split the big text in pieces and store it on a Sqlite3 database.
From there, some other programs to extract the data and build the site. (I set a
trial output site for my friend, just to see the data, formatting is awful and
texts are in spanish... http://watersmurf.homelinux.com/julio.html, select the
left link over the picture)
I would appreciate very much any suggestion to improve the access to Sqlite3
databases.
Thanks for your suggestions!.
Jes.

5. Re: EuSQLite

• Posted by Juergen Luethje <j.lue at gmx.de> Jun 09, 2007
• 604 views

Ray Smith wrote:

> Juergen Luethje wrote:
> > Below there are some other functions which might be faster.
> > I don't know whether that really matter, though.
> > 
> > Regards,
> >    Juergen
> 
> Hi Juergen,
> 
> The "len" variable in the original peek_sequence really was meant to be
> "max_len".
> It didn't need to return a sequence of len, only not > len.
> 
> So peek_sequence1 is not a valid substitute.
> 
> Your peek_sequence2 and 3 look much better though.
> 
> I'd "assume" (I know we should never do that) but peek_sequence3 looks the
> faster
> ... 
> the only problem being it isn't portable to Linux or FreeBSD.

<snip>

Hi Ray and Jesus,

I solved that problem by writing a small cross-platform length()
function for null-terminated strings using ASM. Like you Ray,
currently I only assume that this function is the fastest
(but I think it's an educated guess). :)

-- * Euphoria 2.4 Official Release or later required *
--   (because parameters are passed to machine code)

include machine.e
include dll.e

------------------------------------------------------------------------
constant SL_CODE = allocate(26)

poke(SL_CODE, {
     -- After the routine has pushed 4 bytes on the stack, first int
     -- argument is at stack offset +8.
     #57,                        -- push   edi
     #8B, #7C, #24, #08,         -- mov    edi, [esp+8]
     #B9, #FF, #FF, #FF, #FF,    -- mov    ecx, #FFFFFFFF
     #B0, #00,                   -- mov    al, 0
     #FC,                        -- cld
     #F2, #AE,                   -- repne  scasb
     #B8, #FE, #FF, #FF, #FF,    -- mov    eax, #FFFFFFFE
     #29, #C8,                   -- sub    eax, ecx
     #5F,                        -- pop    edi
     #C2, #04, #00               -- ret    4    -- pop 4 bytes off the stack
   })

global constant
   STRLEN = define_c_func("", SL_CODE, {C_POINTER}, C_ULONG)

-- Usage:
-- len = c_func(STRLEN, {addr})
--
-- 'addr' is a pointer to the first character of a null-terminated
-- string in memory;
-- returns the length of the string in bytes (not including the
-- terminating null character) 

------------------------------------------------------------------------

global function peek_string (atom addr)
   -- read a null-terminated string, starting at address 'addr' in memory
   return peek({addr, c_func(STRLEN,{addr})})   
end function

------------------------------------------------------------------------


-- Demo
sequence s
atom addr

s = "Hello"
-- s = repeat('x', 90000)

addr = allocate_string(s)
printf(1, "len = %d", {c_func(STRLEN,{addr})}) 
free(addr)

Regards,
   Juergen

7. Re: EuSQLite

• Posted by Juergen Luethje <j.lue at gmx.de> Jun 09, 2007
• 596 views

Hi Chris,

thanks for the comprehensive explanation of the background -- which
I didn't know previously. What you wrote makes a lot of sense.

Regards,
   Juergen