OpenEuphoria

1. ex.err & Geany

• Posted by K_D_R Mar 17, 2013
• 4248 views
• Last edited Mar 18, 2013

Forked from Re: EuGeany 1.2

So... If we had a little euphoria program, as you have described, which could be executed from Geany's builtin terminal interface upon a crash/error, it could pass the filename, error line, and error column to Geany. Indeed, multiple files could be opened if necessary, Yes?

Regards, Ken

3. Re: ex.err & Geany

• Posted by K_D_R Mar 18, 2013
• 4094 views

include "std/error.e" 
include "std/text.e" 
 
function geany_crash( integer dummy ) 
   
    integer fn = open( "ex.err", "r" ) 
    if fn = -1 then 
        return 0 
    end if 
     
    object line = gets( fn ) 
    if sequence( line ) then 
 
        line = text:trim( line ) -- e.g. C:\path\to\file:1234 
         
        sequence command = sprintf( "geany \"%s\"", {line} ) 
        system_exec( command ) 
         
    end if 
     
    close( fn ) 
     
    return 0 and dummy 
end function 
crash_routine( routine_id("geany_crash") ) 

I am clueless ... like this?

-- 
-- eugeany.ex 
-- 
-- usage: Geany run_cmd = eui eugeany.ex ./%f 
-- 
-- 
-- 
 
include "std/error.e" 
include "std/text.e" 
 
function geany_crash( integer dummy ) 
   
    integer fn = open( "ex.err", "r" ) 
    if fn = -1 then 
        return 0 
    end if 
     
    object line = gets( fn ) 
    if sequence( line ) then 
 
        line = text:trim( line ) -- e.g. C:\path\to\file:1234 
         
        sequence command = sprintf( "geany \"%s\"", {line} ) 
        system_exec( command ) 
         
    end if 
     
    close( fn ) 
     
    return 0 and dummy 
end function 
crash_routine( routine_id("geany_crash") ) 
 
ifdef DEBUG then 
 crash_routine() 
end ifdef 
 
 
-- it may be possible to simply 
-- set Geany's run_cmd = eui ./%f -D DEBUG 
-- in which case the following code may 
-- not be necessary. 
sequence file_name = "" 
sequence cl = command_line() 
if length(cl) >= 3 then 
 
   ifdef UNIX then 
 
       file_name = cl[3] 
        
       if file_exists("ex.err")  
           
            system("rm " & "ex.err", 0) 
        
       end if 
                                                           
       system("eui \"" & file_name & "\""  & "-D DEBUG", 1) 
    
 
   elsedef 
 
       file_name = lower(cl[3]) 
 
            if file_exists("ex.err") 
             
                 system("del " & "ex.err > NUL", 0)                                                             
          
            end if 
 
 
            if match(".exw", lower(file_name) & "-D DEBUG", 1) or  
                    match(".ew",  lower(file_name)) then 
 
                 system("euiw \"" & file_name & "\"" & "-D DEBUG", 1) 
 
            else 
 
                 system("eui \"" & file_name & "\"" & "-D DEBUG", 1) 
 
            end if 
 
   end ifdef 
 
end if 
    

5. Re: ex.err & Geany

• Posted by K_D_R Mar 18, 2013
• 4006 views
• Last edited Mar 19, 2013

Once more, with feeling...

edit: 2013-03-19 to show error message

 
-- gneui.ex 
-- 
-- 2013 2013-03-18 
-- Kenneth Rhodes <wolfmanjacques@gmail.com> 
-- 
-- 
-- gneui.ex 
-- 
-- usage: Geany run_cmd = eui gneui.ex ./%f 
-- 
include std/io.e 
include std/convert.e 
include std/console.e 
include "std/error.e" 
include "std/filesys.e" 
include "std/text.e" 
include "std/wildcard.e" 
 
file_number err_file 
sequence err_lines 
object temp_line 
sequence msg 
integer TRUE = 1 
 
constant STANDARD_TAB_WIDTH = 8 
 
type natural(integer x) 
    return x >= 0 
end type 
natural start_line, start_col, colon_pos 
 
type positive_int(integer x) 
    return x >= 1 
end type 
 
function tab(natural tab_width, positive_int pos) 
    -- compute new column position after a tab 
    return (floor((pos - 1) / tab_width) + 1) * tab_width + 1 
end function 
 
function expand_tabs(natural tab_width, sequence line) 
    -- replace tabs by blanks in a line of text 
    natural tab_pos, column, ntabs 
     
    column = 1 
    while TRUE do 
	tab_pos = find('\t', line[column..length(line)]) 
	if tab_pos = 0 then 
	    -- no more tabs 
	    return line 
	else 
	    tab_pos += column - 1 
	end if 
	column = tab(tab_width, tab_pos) 
	ntabs = 1 
	while line[tab_pos+ntabs] = '\t' do 
	    ntabs += 1 
	    column += tab_width 
	end while 
	-- replace consecutive tabs by blanks 
	line = line[1..tab_pos-1] &  
	repeat(' ', column - tab_pos) & 
	line[tab_pos+ntabs..length(line)]             
    end while 
end function 
 
sequence file_name = "", command = "" 
integer exit_code = 0 
 
sequence cl = command_line() 
if length(cl) >= 3 then 
    file_name = cl[3] 
    ifdef UNIX then 
	command = sprintf( "eui -D DEBUG \"%s\"", {file_name} ) 
    elsedef 
	if wildcard:is_match( "*.ew", file_name ) 
		or wildcard:is_match( "*.exw", file_name) then 
	    command = sprintf( "euiw -D DEBUG \"%s\"", {file_name} ) 
	else 
	    command = sprintf( "eui -D DEBUG \"%s\"", {file_name} ) 
	end if 
    end ifdef 
     
    if file_exists("ex.err") then 
	delete_file("ex.err") 
    end if 
     
    exit_code = system_exec( command ) 
    if exit_code != 0 then 
	-- from geany_crash() and ed.ex get_err_line 
	err_file = open( "ex.err", "r" ) 
	if err_file = -1 then 
	    msg = "" 
	else 
	    -- read the top of the ex.err error message file 
	     err_lines = {} 
	     while length(err_lines) < 6 do 
		    temp_line = gets(err_file) 
		    if atom(temp_line) then 
			exit 
		    end if 
		    err_lines = append(err_lines, temp_line) 
	    end while 
	    close(err_file) 
	    -- look for file name, line, column and error messag 
	    if length(err_lines) > 1 and match("TASK ID ", err_lines[1]) then 
		err_lines = err_lines[2..$] 
	    end if 
	    if length(err_lines) > 0 then 
		if sequence(err_lines[1]) then 
		    colon_pos = match(".e", lower(err_lines[1])) 
		    if colon_pos then 
			if find(err_lines[1][colon_pos+2], "dxXwWuU") then 
			    colon_pos += 1 
			    if find(err_lines[1][colon_pos+2], "wxWuU") then 
				colon_pos += 1 
			    end if 
			end if 
			file_name = err_lines[1][1..colon_pos+1] 
			start_line = to_integer(err_lines[1][colon_pos+3..length(err_lines[1])]) 
			msg = trim(err_lines[2]) 
			 
			if length(err_lines) > 3 then 
			    start_col = find('^', expand_tabs(STANDARD_TAB_WIDTH,  
						err_lines[length(err_lines)-1])) 
			end if 
 
			-- show error message 
                        if length(error_message) > 0 then                                                                          
                             puts(SCREEN, error_message)                                                                                
                        end if 
                   
			file_name = file_name & ":" & start_line & ":" & start_col 
--                      open file in Geany with cursor placed at error line & column 
			system_exec( sprintf("geany \"%s\"", {file_name}) ) 
		    end if 
		end if 
	    end if 
	end if 
    end if 
end if 
 
 

7. Re: ex.err & Geany

• Posted by ghaberek (admin) Mar 19, 2013
• 3841 views

Shouldn't that geany line be something like this... ?

-- usage: geany path_to_file:line:col 
system_exec( sprintf("geany \"%s:%d:%d\"", {file_name,start_line,start_col}) ) 

-Greg

9. SUCESS! ex.err support for Geany!

• Posted by K_D_R Mar 21, 2013
• 3504 views

Thanks to everyone for the help

This code succeeds in positioning the cursor in the offending file at the line and column of the error as reported by ex.err

For what it is worth, the get_err_line code in ed.ex needs some work. I discovered that it was not setting the cursor at the error column either.

ONE CAVEAT: I suspect that this code might not position the cursor properly on lines with leading tabs.

-- gneui.ex 1.0 
-- 
-- 2013 2013-03-21 
-- Kenneth Rhodes <wolfmanjacques@gmail.com> 
-- 
-- This file wraps the Euphoria interpreter  
-- together with a routine which extracts 
-- ex.err file data and passes the name,  
-- path, line and column to the Geany editor 
--  
-- 
-- usage: Geany run_cmd = eui gneui.ex ./%f 
-- Set run source code command to this as well, 
-- Execute your code from Geany, upon error, 
-- Geany will position the cursor at the line 
-- and column of the error. 
-- 
-- 
include std/io.e 
include std/convert.e 
include std/console.e 
include std/error.e 
include std/filesys.e 
include std/text.e 
include std/wildcard.e 
 
integer err_file, wcmatch 
sequence err_lines  
object temp_line 
sequence msg 
integer TRUE = 1, FALSE = 2 
integer cont = TRUE 
 
type natural(integer x) 
    return x >= 0 
end type 
natural start_line, start_col 
start_line = 1 start_col = 1 
 
object file_name = "", command = "" 
integer exit_code = 0 
 
sequence cl = command_line() 
if length(cl) >= 3 then 
    file_name = cl[3] 
    ifdef UNIX then 
	command = sprintf( "eui -D DEBUG \"%s\"", {file_name} ) 
    elsedef 
	if wildcard:is_match( "*.ew", file_name ) 
	or wildcard:is_match( "*.exw", file_name) then 
	    command = sprintf( "euiw -D DEBUG \"%s\"", {file_name} ) 
	else 
	    command = sprintf( "eui -D DEBUG \"%s\"", {file_name} ) 
	end if 
    end ifdef 
    if file_exists("ex.err") then 
	delete_file("ex.err") 
    end if 
     
    exit_code = system_exec( command ) 
    if exit_code != 0 then 
	err_file = open( "ex.err", "r" ) 
	if err_file = -1 then 
	    msg = "" 
	else 
	    -- read the top of the ex.err error message file 
	    err_lines = {} 
	    while cont do 
		temp_line = gets(err_file) 
		if atom(temp_line) then 
		exit 
		end if 
		 
		err_lines = append(err_lines, temp_line) 
		if find('^', temp_line) then 
		    start_col = match("^", temp_line)-1 
		    cont = FALSE 
		end if 
	    end while 
	     
	    close(err_file) 
	     
	    -- look for file name, line, column and error messag 
	    if length(err_lines) > 0 then 
		file_name = trim(err_lines[1]) 
		msg = trim(err_lines[2]) 
		system_exec( sprintf("geany \"%s:%d:\"", {file_name, start_col}) ) 
	    end if 
	 
	end if 
    end if 
end if 
clear_screen() 
abort(0) 

11. Re: ex.err & Geany

• Posted by K_D_R Mar 22, 2013
• 3363 views

-- usage: geany path_to_file:line:col 
system_exec( sprintf("geany \"%s:%d:%d\"", {file_name,start_line,start_col}) ) 

-- usage: geany path_to_file:line:col 
system_exec( sprintf("geany \"%s\":%d:%d", {file_name,start_line,start_col}) ) 

chdir(pathname(file_name)) 
system_exec( sprintf("geany %s:%d:%d", {filename(file_name),start_line,start_col}) ) 

err_lines = {} 
    while length(err_lines) < 6 do 
        temp_line = gets(err_file) 
        if atom(temp_line) then 
        exit 
        end if 
        err_lines = append(err_lines, temp_line) 
    end while 
    close(err_file) 

The problem was a simple bug in the ed.ex "get_err_line" routine:

err_lines = {} 
    while length(err_lines) < 6 do  --<----------- only 6 lines are being read 
                                    -- the '^' marking the error column was found 
                                    -- on line 9 
 
        temp_line = gets(err_file) 
        if atom(temp_line) then 
        exit 
        end if 
        err_lines = append(err_lines, temp_line) 
    end while 
    close(err_file) 

I resolved the problem by continuing to read lines from the file, until the '^' is matched:

err_lines = {}  
	    while cont do  
		temp_line = gets(err_file)  
		if atom(temp_line) then  
		exit  
		end if  
		  
		err_lines = append(err_lines, temp_line)  
		if find('^', temp_line) then  
		    start_col = match("^", temp_line)-1  
		    cont = FALSE  
		end if  
	    end while  
	      
	    close(err_file)  

13. Re: ex.err & Geany

• Posted by K_D_R Mar 24, 2013
• 3279 views

    file_name = trim(err_lines[1]) -- nb file_name is eg "path\test.ex:85" 

Point taken. Your comments and suggestions are appreciated.

This is my latest effort:

-- gneui.ex 1.0 
-- 
-- 2013 2013-03-21 
-- Kenneth Rhodes <wolfmanjacques@gmail.com> 
-- 
-- This file wraps the Euphoria interpreter 
-- together with a routine which extracts 
-- ex.err file data and passes the name, 
-- path, line and column to the Geany editor 
-- 
-- 
-- usage: Geany run_cmd = eui gneui.ex ./%f 
-- Set run source code command to this as well, 
-- Execute your code from Geany, upon error, 
-- Geany will position the cursor at the line 
-- and column of the error. 
-- 
-- 
include std/io.e 
include std/convert.e 
include std/console.e 
include std/error.e 
include std/filesys.e 
include std/text.e 
include std/wildcard.e 
 
integer err_file, wcmatch 
sequence err_lines 
object temp_line 
sequence msg 
integer TRUE = 1, FALSE = 2 
integer cont = TRUE 
 
type natural(integer x) 
    return x >= 0 
end type 
natural start_line, start_col 
start_line = 1 start_col = 1 
 
object file_name = "", command = "" 
integer exit_code = 0 
 
procedure get_err_line() 
err_file = open( "ex.err", "r" ) 
    if err_file = -1 then 
	msg = "" 
    else 
	-- read the top of the ex.err error message file 
    err_lines = {} 
    while cont do 
	temp_line = gets(err_file) 
	if atom(temp_line) then 
	exit 
	end if 
	err_lines = append(err_lines, temp_line) 
	if find('^', temp_line) then 
	start_col = match("^", temp_line)-1 
	cont = FALSE 
	end if 
    end while 
    close(err_file) 
	-- look for file name, line, column and error messag 
    if length(err_lines) > 0 then 
	file_name = trim(err_lines[1])  -- eg: path/test.ex:18 
	msg = trim(err_lines[2]) 
	system( sprintf("geany \"%s:%d:\"", {file_name, start_col} ) ) 
    end if 
    end if 
end procedure 
 
sequence cl = command_line() 
clear_screen() 
if length(cl) >= 3 then 
    file_name = cl[3] 
    ifdef UNIX then 
    command = sprintf( "eui -D DEBUG \"%s\"", {file_name} ) 
    elsedef 
    if wildcard:is_match( "*.ew", file_name ) 
    or wildcard:is_match( "*.exw", file_name) then 
	command = sprintf( "euiw -D DEBUG \"%s\"", {file_name} ) 
    else 
	command = sprintf( "eui -D DEBUG \"%s\"", {file_name} ) 
    end if 
    end ifdef 
 
    if  file_exists("ex.err") then 
    delete_file("ex.err") 
    end if 
 
    exit_code = system_exec ( command, 0 ) 
    if exit_code != 0 then 
    get_err_line() 
    end if 
else 
    get_err_line() 
end if 
clear_screen() 
abort(0)