OpenEuphoria

2. Re: EuGTK Days Between Dates

• Posted by irv Jul 20, 2018
• 2753 views

Nice! Here's a different take on it, using calendars to click and date parsing, so various formats can be typed in:

--  
--  GTK Days Between Dates, requires OpenEuphoria 4.x  
--  a simple EuGTK demo program by Kenneth Rhodes  
--  
--  Check out Irv Mullins EuGTk 4.14.0  
--  https://sites.google.com/site/euphoriagtk/Home/  
--  
--  Added a couple calendars for ease of use - Irv 
--  Dates can be typed in using various formats, 
--  or selected from the calendars via mouse. 
  
include std/datetime.e  
include GtkEngine.e  
  
constant instructions = {  
"Calculate the number of days between dates",   
"""  

Select start and end dates from the calendars, then  
click the OK button, or type a date into the box below 
the calendar. 
 
Date formats include: m/d/yy, m/d/yyyy, yyyy/m/d, etc. 
Experiment!  
  
The program displays the number of days between the   
starting and ending date as well as the week day names  
of the starting and ending dates  
  
"""}  

 
constant -- INTERFACE  
    win = create(GtkWindow,"title = Compute Days Between Dates,border=10,$destroy=Quit"),  
    pan = create(GtkBox,"orientation=vertical,spacing=10"),  
    cal1 = create(GtkCalendar,"name=cal1,font=8,$day-selected=Update"), 
    StartDate = create(GtkEntry,"placeholder text=Start Date,$activate=Parse,data=cal1"), 
    cal2 = create(GtkCalendar,"name=cal2,font=8,$day-selected=Update"),  
    EndDate = create(GtkEntry,"placeholder text=End Date,$activate=Parse,data=cal2"),  
      
    btnbox = create(GtkButtonBox),  
    btn1 = create(GtkButton,"gtk-quit","Quit"),  
    btn2 = create(GtkButton,"gtk-help","Help"),  
    btn3 = create(GtkButton,"gtk-ok","GetDaysBetweenDates")  
      
    gtk:add(win,pan)  
    gtk:add(pan,{cal1, StartDate, cal2, EndDate})  
      
    pack_end(pan,btnbox)  
    gtk:add(btnbox,{btn1,btn2,btn3})  
    set(btn3,"grab focus")  
      
show_all(win)  
main()  
  
--------------------------------------------------------------------------------  
--         You might want to add these functions to std/datetime.e            --  
-------------------------------------------------------------------------------- 
global function DaysBetweenDates(datetime dt1, datetime dt2)               
	return floor(diff(dt1,dt2)/86400)  -- 86400 = seconds in a day           
end function                                                                                              --                                                                              
--------------------------------------------------------------------------------  
 
-------------------------  
global function Help() --  
------------------------- 
    return Info(win,"instructions",instructions[1],instructions[2])  
end function  
  
--------------------------- 
global function Update() -- update date displays whenever either changes; 
--------------------------- 
set(StartDate,"text",get(cal1,"date",0))  
set(EndDate,"text",get(cal2,"date",0)) 
return 1 
end function 
 
----------------------------------------------  
global function Parse(atom ctl, object cal) -- 
---------------------------------------------- 
object cdate = get(ctl,"text") 
cal = unpack(cal) -- get target calendar;  
object dt = datetime:parse(cdate,"%m %d %Y") 
     
 if atom(dt) then dt = datetime:parse(cdate,"%d %m %Y") end if  
 if atom(dt) then dt = datetime:parse(cdate,"%y %m %d") end if 
 if atom(dt) then dt = datetime:parse(cdate,"%Y %m %d") end if 
 if atom(dt) then dt = datetime:parse(cdate,"%Y %d %m") end if 
 
 if atom(dt) then 
    set(ctl,"text",cdate & " <- ERROR") 
    set(ctl,"color","red") 
 else 
   if dt[1] < 1900 then dt[1] += 1900 end if 
      set(cal,"date",dt) -- set target calendar; 
      set(ctl,"color","black") 
 end if	 
return 1 
end function 
 
----------------------------------------- 
global function GetDaysBetweenDates()  --  
----------------------------------------- 
Update() -- make sure dates are displayed in entry boxes; 
atom dbd  
object  
 dt1 = get(cal1,"datetime"), -- dt format to compute with; 
 dt2 = get(cal2,"datetime"), 
 dd1 = get(cal1,"date",0), -- default format for display; 
 dd2 = get(cal2,"date","%A, %B %d,\nwhich is day %j of the year %Y") -- custom fmt; 
  
 dbd = DaysBetweenDates(dt1,dt2)  
  
 Info(win, "Days Between Dates",  
	text:format("There are [] days",dbd), 
	text:format("between <b>[]</b>\nand <b>[]</b>", {dd1,dd2}))  
	  
return 1  
end function  
 

4. Re: EuGTK Days Between Dates

• Posted by Senator Jul 24, 2018
• 2636 views

-- The custom format display is the same as the default format 
-- on my system 
 
dd1 = get(cal1,"date",0), -- default format for display;  
-- Tuesday, 24 Jul, 2018  -- display 
 
dd2 = get(cal2,"date","%A, %B %d,\nwhich is day %j of the year %Y")  
-- Thursday, 18 Oct, 2018   -- display 
 
-- infobox display also reports the default format 
-- for dd2: 
-- "There are 86 days"  
-- "between Tuesday, 24 Jul, 2018" 
-- "and Thursday, 18 Oct, 2018" 

6. Re: EuGTK Days Between Dates

• Posted by Senator Jul 25, 2018
• 2587 views

Thanks to Irv for the updated parse function.

Regarding my problem with the custom display format...

dd1 = get(cal1,"date",0), -- default format for display;  
-- Displays Thursday, 18 Oct, 2018 
 
-- custom format for display 
dd2 = get(cal2,"date","%A, %B %d,\nwhich is day %j of the year %Y")   
-- Displays Thursday, 18 Oct, 2018 --same as default format 

While exploring one of the new demo programs in your latest
EuGTK 4.14.0 release I encountered an error message advising
me that the code requires GTK3 3.20 and that I have 3.18.9
installed on my Ubuntu 16.04 LTS computer.

So, I speculated that the custom display format might require
GTK3 3.20 and that might account for the display of the default
format as opposed to the custom display format. Perhaps I should
upgrade to the latest Ubuntu release.

Does the custom date display option require GTK3 3.20?

Regards,
Ken Rhodes