OpenEuphoria

1. little graphic user interfaces - how to program on WinXP system

• Posted by han45 Nov 21, 2014
• 1814 views

Hello everybody outside in the deep blue sea of bits and bytes ,

how is it possible to program little graphic user interfaces in euphoria , with WIN XP system ?

There are only DOS programming statements available. I have the Beginners Tutorial from David Gay.

Dos Box is good for testing purposes. But i dont think that "The Same DOS Code of Euphoria" works on WinXP.

It is important to create a pixel graphics window in full screen for display.

This GUI i want to "include" my program code.

See you

+

Thank you very much for the handshake.

I have win32.lib already installed. For running a program from archieve download.

Found the wxeuphoria homepage with the documentation.

Hans

Uhhhhhhhhhhh , i am here , in the deep blue sea of bits and bytes.

There is a strong wind...

But i a m prepared with the "Euphoria Yacht" to pass the water with pleasure.

See you later ...

The Byte-Surfer

3. Re: little graphic user interfaces - how to program on WinXP system

• Posted by ghaberek (admin) Nov 21, 2014
• 1810 views

For this you should see Starting Euphoria Gui Programming. There are several options available. The easiest library to get started with is Win32Lib.

You can download Win32Lib from this link: http://sourceforge.net/projects/win32libex/

Extract the zip file into a new folder named "Win32Lib" in your Euphoria folder (typically that's C:\Euphoria).

Edit your eu.cfg and add the path to the Win32Lib "Include" folder.

[all] 
-d E32 
-eudir C:\Euphoria 
-i C:\Euphoria\include 
-i C:\Euphoria\Win32Lib\Include  # add this line 

Here is a simple Win32Lib example. Save this as demo.exw and run with euiw.exe.

include Win32Lib.ew 
 
-- create a simple window 
constant myWindow = create( 
    Window,  -- control type (a standard Window) 
    "Demo",  -- caption of this Window (title bar text) 
    0,       -- parent of this Window (0 = no parent) 
    Default, -- initial x position (Default = let Windows choose) 
    Default, -- initial y position (Default = let Windows choose) 
    320,     -- initial width 
    240,     -- initial height 
    0 )      -- additional styles (0 = default) 
 
-- create a simple text label 
constant myLabel = create( 
    LText,    -- control type (LText means "left-aligned text") 
    "Hello!", -- caption of this LText (the value displayed on the label) 
    myWindow, -- parent of this control (our 'myWindow' from above) 
    10,       -- initial x position 
    10,       -- initial y position 
    200,      -- initial width 
    20,       -- initial height 
    0 )       -- additional styles (0 = default) 
 
-- create a simple push button 
constant myButton = create( 
    PushButton, -- control type (a standard button) 
    "Click Me", -- caption of this button 
    myWindow,   -- parent of this control 
    10,         -- initial x position 
    40,         -- initial y position 
    90,         -- initial width 
    30,         -- initial height 
    0 )         -- additional styles (0 = default) 
 
-- change the font of the LText control 
setFont( myLabel, "MS Sans Serif", 12, Bold ) 
 
-- create an event handler for the button's "Click" event 
-- 
--   Note: these parameters are standard to all event handlers. 
--   see the documentation for the values contained in 'params' 
--   which is specific to each event. 
-- 
procedure myButton_OnClick( integer self, integer event, sequence params )  
     
    -- show a message box when the user clicks the button 
    message_box( 
        "You clicked the button!", -- the message to display 
        "Clicked!",                -- the caption for the message box 
        MB_OK+MB_ICONINFORMATION ) -- the style of the box (buttons, icons, etc.) 
     
end procedure 
 
-- assign the event handler to the button 
setHandler( 
    myButton,                      -- the control whose events we want to handle 
    w32HClick,                     -- the event of the control we want to handle 
    routine_id("myButton_OnClick") -- the routine we want to handle the events 
) 
 
-- start the application by opening 'myWindow' in 'Normal' mode, 
--   other options include 'Maximized' or 'Minimized' 
WinMain( myWindow, Normal ) 

Hope this helps,

-Greg

5. Re: little graphic user interfaces - how to program on WinXP system

• Posted by evanmars Nov 21, 2014
• 1772 views

Isn't EuGTK Linux only?

7. Re: little graphic user interfaces - how to program on WinXP system

• Posted by kinzz Nov 21, 2014
• 1762 views

Try please the Dos_Rescue thing: http://www.rapideuphoria.com/cgi-bin/asearch.exu?dos=on&win=on&lnx=on&gen=on&keywords=insolor

Regards

9. Re: little graphic user interfaces - how to program on WinXP system

• Posted by ghaberek (admin) Nov 21, 2014
• 1702 views

That's okay, I really only half-agree with what I said anyway. I think that what makes Win32Lib "easy" is that its 100% Euphoria code. The external libraries or packages required for wxEuphoria and EuGTK complicate things and add to the learning curve. I think it's "easier" to start with Win32Lib and then move on to wxEuphoria or EuGTK after getting one's feet wet, so to speak.

-Greg

11. Re: little graphic user interfaces - how to program on WinXP system

• Posted by andi49 Nov 21, 2014
• 1691 views

Hallo Hans

schreib einfach eine email. (einfach andi49 anklicken da ist eine adresse hinterlegt) vielleicht kann ich Dir helfen.
Deutsch ist auch fuer mich einfacher.Aber ich moechte das Forum hiermit nicht belasten ;)

Andreas