OpenEuphoria

2. Re: Detecting network and/or inet

• Posted by jimcbrown (admin) Sep 09, 2016
• 1385 views

I think you can use "cmd /c start /b" or something along those lines to hide the cmd window.

4. Re: Detecting network and/or inet

• Posted by ghaberek (admin) Sep 09, 2016
• 1405 views

Adapted from my previous response eleven years ago.

Re: Is this computer connected to the Internet

-- InternetGetConnectedState function 
-- https://msdn.microsoft.com/en-us/library/windows/desktop/aa384702(v=vs.85).aspx 
 
include std/dll.e 
include std/machine.e 
 
constant wininet = open_dll( "wininet.dll" ) 
constant xInternetGetConnectedState = define_c_func( wininet, 
    "InternetGetConnectedState", {C_POINTER,C_LONG}, C_INT ) 
 
ifdef not EU4_1 then 
function sizeof( atom ctype ) 
    return and_bits( ctype, #FF ) 
end function 
end ifdef 
 
public constant 
    INTERNET_CONNECTION_MODEM       = #01, 
    INTERNET_CONNECTION_LAN         = #02, 
    INTERNET_CONNECTION_PROXY       = #04, 
    INTERNET_CONNECTION_MODEM_BUSY  = #08,    -- no longer used 
    INTERNET_RAS_INSTALLED          = #10, 
    INTERNET_CONNECTION_OFFLINE     = #20, 
    INTERNET_CONNECTION_CONFIGURED  = #40, 
$ 
 
public function InternetGetConnectedState() 
     
    atom lpdwFlags = allocate( sizeof(C_POINTER), 1 ) 
    atom dwFlags = 0 
    atom dwReserved = 0 
     
    atom result = c_func( xInternetGetConnectedState, {lpdwFlags,dwReserved} ) 
    dwFlags = peek4u( lpdwFlags ) 
     
    return {result,dwFlags} 
end function 

Example:

include std/utils.e 
include internet.e 
 
sequence result = InternetGetConnectedState() 
sequence status = iff( result[1], "Online", "Offline" ) 
 
printf( 1, "status = %s (flags = #%02x)\n", {status,result[2]} ) 

Output:

status = Online (flags = #12) 

-Greg

6. Re: Detecting network and/or inet

• Posted by jimcbrown (admin) Sep 10, 2016
• 1370 views

Perhaps looking at this example might help:

http://www.winsocketdotnetworkprogramming.com/winsock2programming/winsock2advancediphelperfunction13h.html