OpenEuphoria

1. Euphoria sucks at golfing

• Posted by ghaberek (admin) May 07, 2014
• 1709 views

It's been a while since we've discussed code golf. I think it's a good mental exercise and quite a bit of fun. Unfortunately, due to its verbose nature, Euphoria results tend to be a worse than other languages, especially curly bracket languages that lack "end <construct>" type statements.

Here's a fun problem: Bring out the inner llama of a sentence

Pie is good.  I just ate a bunch of pies early this morning.  Actually, it was closer to the afternoon.  Mornings are good. 

Pie is good.  I just ate a bunch of pies early this morning.  Actually, it was closer to the afternoon.  Mornings are good. 
                                            ^                      ^        ^                            ^        ^ 

[44, 67, 76, 105, 114] 

Here is my solution...

include std/text.e 
 
object T = gets(0), 
    t = lower(T), 
    L = "llama", 
    X = repeat(0,5) 
 
for i = 1 to length(L) do 
    if i = 1 then 
        X[i] = find(L[i],t) 
    else 
        X[i] = find(L[i],t,X[i-1]+1) 
    end if 
    if X[i] = 0 then 
        X = {} 
        exit 
    end if 
end for 
 
? X 

Output:

{45,68,77,106,115} 

Total of 180 characters (worst by far according to other answers). It accepts a string via STDIN, e.g.

echo "Pie is good.  I just ate a bunch of pies early this morning.  Actually, it was closer to the afternoon.  Mornings are good." | eui llama.ex 

-Greg

3. Re: Euphoria sucks at golfing

• Posted by jimcbrown (admin) May 07, 2014
• 1635 views

Here's my attempt:

include std/text.e 
 
object t = lower(gets(0)), 
    L = "llama", 
    X = 0&"     " 
 
for i = 1 to length(L) do 
    X[i+1] = find(L[i],t,X[i]+1) 
    if X[i+1] = 0 then 
        X = {0} 
        exit 
    end if 
end for 
 
? X[2..$] 

5. Re: Euphoria sucks at golfing

• Posted by jaygade May 07, 2014
• 1635 views
• Last edited May 08, 2014

I got it down to 150 characters (after whitespace removed). Here's the whitespace version:

object t=and_bits(gets(0),#DF),L="LLAMA",X={},i=1 
 
while length(L) do 
  i=find(L[1],t,i) 
  if i=0 then 
    X={} 
    exit 
  else 
    L=L[2..$] 
    X&=i 
    i+=1 
  end if 
end while 
?X 

Edit: Shortened to 148:

object t=and_bits(gets(0),#DF),L="LLAMA",X={},i=1 
 
while length(L)do 
  i=find(L[1],t,i) 
  if i then 
    L=L[2..$] 
    X&=i 
    i+=1 
  else 
    X={} 
    exit 
  end if 
end while 
?X 

Edit2 Got it down to 147. Here is the short version:

object t=and_bits(gets(0),#DF),L="LLAMA",X={},i=1 
while length(L)do 
i=find(L[1],t,i)if i then L=L[2..$]X&=i i+=1 
else X={}exit 
end if 
end while 
?X 

7. Re: Euphoria sucks at golfing

• Posted by jaygade May 07, 2014
• 1608 views

Whittled down to 141:

object t=and_bits(gets(0),#DF),L="LLAMA",i=0,X={} 
 
while length(L) do 
  i=find(L[1],t,i+1) 
  X&=i 
  L=L[2..$] 
end while 
 
if find(0,X) then 
  X={} 
end if 
?X 

9. Re: Euphoria sucks at golfing

• Posted by jaygade May 07, 2014
• 1580 views

I'm not sure that or_bits would work. Aren't you only setting bit 4 and not masking any others?

Hmm, testing finds that you could get some errors, although it should work most of the time.

Edit: My testing finds an off-by-one error, but you might be able to correct for that.

11. Re: Euphoria sucks at golfing

• Posted by mattlewis (admin) May 08, 2014
• 1560 views

This gets down to 130:

object o=and_bits(gets(0),#DF),l="LLAMA",x=0,y={} 
for i=1 to 5 do 
x=find(l[i],o,x+1)if x=0 then 
?{}abort(0)end if 
y&=x 
end for 
?y 

Readable:

object 
	o = and_bits(gets(0),#DF), 
	l="LLAMA", 
	x=0, 
	y={} 
for i=1 to 5 do 
	x=find(l[i],o,x+1) 
	if x=0 then 
		?{} 
		abort(0) 
	end if 
	y &= x 
end for 
?y 

13. Re: Euphoria sucks at golfing

• Posted by PeteE May 08, 2014
• 1534 views

if find(0,X) then X={} end if 
?X 

could be replaced with

?X[1..$*not find(0,X)] 

15. Re: Euphoria sucks at golfing

• Posted by petelomax May 09, 2014
• 1507 views

This works in Phix (105 characters)

object t=lower(gets(0)),L="llama",i=0for j=1to 5do i=find(L[j],t,i+1)L[j]=i end for?L[1..-not find(0,L)] 

Notes: lower() is an autoinclude, I overwrite L with the result as we go, and finally use negative indexes.

Pete

17. Re: Euphoria sucks at golfing

• Posted by PeteE May 09, 2014
• 1491 views

object t=lower(gets(0)),L=1&"llama"for j=2to 6do L[j]=find(L[j],t,L[j-1]) end for?L[2..-not find(0,L)] 

The first two 'L's will have the same position, since the find starts at the same position as the last letter found. Also when a letter is not found, the slice length will be negative L[2..0] resulting in an error.