OpenEuphoria

1. How to convert sequence of characters to numbers

• Posted by casey Oct 18, 2012
• 1572 views

I need to convert a date/time string (sequence) of the format "20121018123010" into a sequence of numeric values of the format {2012,10,18,12,30,10} I'm looking for the fastest routine execution time possible. It looks like I could use breakup() and then maybe to_integer() or value() on each of the six elements. Am I missing something or is there a better way. Ultimately I need to poke2 each of the word values into a c_func call

Thanks, casey

3. Re: How to convert sequence of characters to numbers

• Posted by useless_ Oct 19, 2012
• 1495 views

 
sequence s = "20121018123010" 
s -= '0' 
integer year = s[1]*1000 + s[2]*100 + s[3]*10 + s[4] -- year is now 2012 

Umm, s[1] is '2' , not 2, and '2' = 50, 2 = 2. Likewise s[1..4] = "2012".

I think you get the idea.

useless

5. Re: How to convert sequence of characters to numbers

• Posted by casey Oct 19, 2012
• 1467 views

Thanks very much. Your solution is simpler and indeed 2x+ faster than calling breakup() and then to_number().

Casey

7. Re: How to convert sequence of characters to numbers

• Posted by ghaberek (admin) Oct 19, 2012
• 1521 views

Obligatory XKCD reference: Regular Expressions

include "std/convert.e" 
include "std/regex.e" 
 
regex pattern = regex:new( "([0-9]{4})([0-9]{2})([0-9]{2})([0-9]{2})([0-9]{2})([0-9]{2})" ) 
 
function get_parts( sequence string ) 
 
    sequence parts = {} 
 
    if regex:is_match( pattern, string ) then 
 
        object matches = regex:matches( pattern, string ) 
 
        parts = repeat( 0, length(matches)-1 ) 
        for i = 1 to length(matches)-1 do 
            parts[i] = to_integer( matches[i+1] ) 
        end for 
 
    end if 
 
    return parts 
end function 

Example:

sequence string = "20121018123010" 
sequence parts = get_parts( string ) 
 
printf( 1, "string = \"%s\"\n", {string} ) 
puts( 1, "parts = " ) ? parts 

Output:

$ eui regex-test.ex  
string = "20121018123010" 
parts = {2012,10,18,12,30,10} 

-Greg

9. Re: How to convert sequence of characters to numbers

• Posted by ghaberek (admin) Oct 20, 2012
• 1431 views

Dang it, you're right. I just did some tests on over 500,000 iterations; the method proposed by you, Spock, and Kat is over 25 times faster than using my regular expression.

However, using a regular expression makes it easier to:

• quickly parse the 'number' out of a string or text file
• validate the input on one pass: it either matches or it doesn't
• allow for any number of variations and/or strictness in the input, e.g.
  • 'year' can only be 1970-2012
  • 'month' can only be 01-12
  • 'day' can only be 01-31
  • 'hour' can only be 00-23
  • 'minute' and 'second' can only be 00-59

Here is the function I used against mine for testing...

function get_parts( sequence string ) 
     
    string -= '0' 
     
    sequence parts = repeat( 0, 6 ) 
    parts[1] = (string[1] * 1000) + (string[2] * 100) + (string[3] * 10) + string[4] 
    parts[2] = (string[5] * 10) + string[6] 
    parts[3] = (string[7] * 10) + string[8] 
    parts[4] = (string[9] * 10) + string[10] 
    parts[5] = (string[11] * 10) + string[12] 
    parts[6] = (string[13] * 10) + string[14] 
     
    return parts 
end function 

-Greg