OpenEuphoria

1. map anomaly

• Posted by bugmagnet Aug 04, 2012
• 1324 views

So a map is an atom. Ok, have got that down pat. So how does Euphoria tell the difference between an atom created with map and a normal atom? In the following code, the map and the atom resolve to the value of 1. map() claims that both are maps. And pairs gives me the same pairs that x has when given the value of y. Anomalous, no?

include std/map.e 
 
map x = new() 
atom y = 1 
 
printf( 1, "x(a map)=%d, y(an atom)=%d\n", {x,y}) 
printf( 1, "map(x)=%d, map(y)=%d\n", {map(x),map(y)}) 
 
sequence xpairs 
sequence ypairs 
 
xpairs = pairs(x) 
ypairs = pairs(y) 
 
if equal(xpairs, ypairs) then 
	puts(1, "anomaly" ) 
else 
	puts(1, "expected" ) 
end if 

>maptest.ex 
x(a map)=1, y(an atom)=1 
map(x)=1, map(y)=1 
anomaly 

Kind regards,
Bruce/bugmagnet

P.S. If this is a bug, I'm demonstrating my magnetism

3. Re: map anomaly

• Posted by bugmagnet Aug 04, 2012
• 1271 views

Yeah but 1+1 and 4/2 are both arithmetic expressions whereas I'm trying to differentiate between a number and reference to a map.

So what this seems to imply is that if I want to pass a map back from a function and differentiate it from an atom of the same value, then I have to abstract it by doing something like {ISMAP, x} and {ISINTEGER, x}. Somehow, I think I'd prefer to know the actual address, but if abstraction is the only way, so be it. Personally, though, I'm not impressed.

Kind regards,
Bruce/bugmagnet

5. Re: map anomaly

• Posted by useless_ Aug 04, 2012
• 1283 views

Give the first (or last) element of your maps a unique label, then you can test that element in that object for being a map in a type test you write.

useless

7. Re: map anomaly

• Posted by useless_ Aug 04, 2012
• 1223 views

Your runtime type check code cannot open the map and look at the first (or last) element, thereby doing a pass/fail on opening the map and a pass/fail on the first (or last) element?

WhatEverNickYouLikeHere

9. Re: map anomaly

• Posted by ghaberek (admin) Aug 04, 2012
• 1313 views

Let me demonstrate how I use maps and it may help you understand what you can do with them.

I generally use maps to create "class-like" objects in Euphoria. Here is a quick example.

C++ code (see: Simple_class_example)

// simple_class_example.cpp 
class Person { 
public: 
      Person(string name, int age) { 
            this->name = name; 
            this->age = age; 
      } 
      string getName() { 
            return name; 
      } 
      int getAge() { 
            return age; 
      } 
private: 
      string name; 
      int age; 
}; 
 
int main() { 
      cout << "Creating a person..." << endl; 
 
      Person johnDoe("John Doe", 25); 
      cout << "Person's name: " << johnDoe.getName() << endl; 
      cout << "Person's age: " << johnDoe.getAge() << endl; 
 
      return 0; 
} 

Euphoria code

-- person.e 
namespace person 
 
include std/map.e 
 
public type person( object p ) 
 
    -- make sure this is at least a map 
    if not map(p) then 
        return 0 
    end if 
 
    -- verify this is a person object by checking 
    -- that some or all of the properties exist 
    return map:has(p, "name") and map:has(p, "age") 
end type 
 
public function new( sequence name, integer age ) 
 
    -- create a small map to hold just a few values 
    map p = map:new( threshold() ) 
 
    -- store some values in the 'object' 
    map:put( p, "name", name ) 
    map:put( p, "age", age ) 
 
    return p 
end function 
 
public function get_name( person p ) 
    sequence name = map:get( p, "name" ) 
    return name 
end function 
 
public function get_age( person p ) 
    integer age = map:get( p, "age" ) 
    return age 
end function 

Testing...

include person.e 
 
procedure main() 
 
    puts( 1, "Creating a person...\n" ) 
 
    person johnDoe = person:new( "John Doe", 25 ) 
 
    if person( johnDoe ) then 
        printf( 1, "Person's name: %s\n", {person:get_name(johnDoe)} ) 
        printf( 1, "Person's age: %d\n", {person:get_age(johnDoe)} ) 
    end if 
 
    atom steveSmith = 5 
 
    if not person( steveSmith ) then 
        printf( 1, "steveSmith is not a person!\n" ) 
    end if 
 
end procedure 

-Greg