OpenEuphoria

2. Re: Turning a Text Sequence into a Sequence Array

• Posted by jimcbrown (admin) Jul 08, 2010
• 3728 views

Use split() from std/sequence.e

4. Re: Turning a Text Sequence into a Sequence Array

• Posted by DanM Jul 09, 2010
• 3697 views

And the strok lib, "sting token routines", can be found at:

http://www.rapideuphoria.com/strtok-v2-1.zip

Dan M

6. Re: Turning a Text Sequence into a Sequence Array

• Posted by DerekParnell (admin) Jul 09, 2010
• 3657 views

With Euphoria v4, the standard library module sequence.e contains the split function. It can be used like this ...

include std/console.e 
include std/sequence.e 
sequence text = "This is only theoretically a sentence." 
 
sequence result = split(' ', text) 
 
display (result) 

The output would be ...

{ 
  "This", 
  "is", 
  "only", 
  "theoretically", 
  "a", 
  "sentence." 
} 

8. Re: Turning a Text Sequence into a Sequence Array

• Posted by DanM Jul 09, 2010
• 3743 views

Oh, ok, when I searched the archive, 2.1 was the only one I found there, where's 2.2 or 3.0?

Dan

10. Re: Turning a Text Sequence into a Sequence Array

• Posted by sergelli Jul 11, 2010
• 3506 views

tested, work fine.

sequence res,sentence 
sentence="This is only theoretically a sentence."  
res={} 
while 1=1 do 
 if not find(32,sentence) then 
	 res&={sentence} 
	 exit 
	end if 
	res&={sentence[1..find(32,sentence)]} 
 sentence=sentence[find(32,sentence)+1..length(sentence)] 
end while	 

12. Re: Turning a Text Sequence into a Sequence Array

• Posted by Kaladan Jul 12, 2010
• 3408 views

Hey, thanks for all the help and advice. Much appreciated! This however leads to another (set of) question(s)...why isn't "std/sequence.e" found anywhere in my install? Was there something I forgot or neglected to download? I know, I know I sound like such a neophyte, but this is something I've wondered since I read the manual. Any help there?

14. Re: Turning a Text Sequence into a Sequence Array

• Posted by Kaladan Jul 13, 2010
• 3368 views

Sorry so slow to reply. I've got 3.11 installed.

16. Re: Turning a Text Sequence into a Sequence Array

• Posted by Kaladan Jul 13, 2010
• 3351 views

Okay, thanks! I've always been wary of betas, but I'll give it a go! Thank you very much!

18. Re: Turning a Text Sequence into a Sequence Array

• Posted by jimcbrown (admin) Jul 14, 2010
• 3276 views

I have a version of split() that works as far back as Euphora 2.2, if you prefer to use an older version of Euphoria until 4.0 is out of beta.

-- (c) Copyright - See License.txt 
-- 
 
global function find_from(object delim, sequence st, integer start) 
	integer ret 
	ret = find(delim, st[start..length(st)]) 
	if ret then 
		ret = ret + start - 1 
	end if 
	return ret 
end function 
 
global function match_from(object delim, sequence st, integer start) 
	integer ret 
	ret = match(delim, st[start..length(st)]) 
	if ret then 
		ret = ret + start - 1 
	end if 
	return ret 
end function 
 
global function split_with_limits(object delim, sequence st, integer limit, integer no_empty) 
	sequence ret 
	integer start 
	integer pos 
	integer k 
 
	ret = {} 
 
	if length(st) = 0 then 
		return ret 
	end if 
 
 
	if sequence(delim) then 
		-- Handle the simple case of split("", "123"), opposite is join({"1","2","3"}, "") -- "123" 
		if equal(delim, "") then 
			for i = 1 to length(st) do 
				st[i] = {st[i]} 
				limit -= 1 
				if limit = 0 then 
					st = append(st[1 .. i],st[i+1 .. length(st)]) 
					exit 
				end if 
			end for 
 
			return st 
		end if 
 
		start = 1 
		while start <= length(st) do 
			pos = match_from(delim, st, start) 
 
			if pos = 0 then 
				exit 
			end if 
 
			ret = append(ret, st[start..pos-1]) 
			start = pos+length(delim) 
			limit -= 1 
			if limit = 0 then 
				exit 
			end if 
		end while 
	else 
		start = 1 
		while start <= length(st) do 
			pos = find_from(delim, st, start) 
 
			if pos = 0 then 
				exit 
			end if 
 
			ret = append(ret, st[start..pos-1]) 
			start = pos + 1 
			limit -= 1 
			if limit = 0 then 
				exit 
			end if 
		end while 
	end if 
 
	ret = append(ret, st[start..length(st)]) 
 
	k = length(ret) 
	if no_empty then 
		k = 0 
		for i = 1 to length(ret) do 
			if length(ret[i]) != 0 then 
				k += 1 
				if k != i then 
					ret[k] = ret[i] 
				end if 
			end if 
		end for 
	end if 
 
	if k < length(ret) then 
		return ret[1 .. k] 
	else 
		return ret 
	end if 
end function 
 
global function split(object delim, sequence st) 
	return split_with_limits(delim, st, 0, 0) 
end function 
 
object result 
result = split(" ", "John Middle Doe") 
for i = 1 to length(result) do 
	puts(1, "|"&result[i]&"|\n") 
end for 

20. Re: Turning a Text Sequence into a Sequence Array

• Posted by Kaladan Jul 14, 2010
• 3266 views

Thanks again, one and all. I got with the program and installed version 4, got the libraries I was looking for. Going good so far. I'm in the planning stages of building an advanced AI chatbot, but I needed to separate the words into an array for very complex word/sentence/context recognition procedures. Not to sound like a commercial but Euphoria has been the best language I've found to try to write the thing in. Glad I ran across it! If I run into any more difficulties, this is where I know to be!

22. Re: Turning a Text Sequence into a Sequence Array

• Posted by useless Jul 17, 2010
• 3131 views

I yanked all the eu code a couple yrs ago. No one wants an intelligent bot of any sort. There was no one programming in eu that was interested either.

useless