OpenEuphoria

1. Fun Test Problem

• Posted by euphoric (admin) May 09, 2010
• 1991 views

See here.

Post your results!

3. Re: Fun Test Problem

• Posted by useless May 22, 2010
• 1732 views

There's not enough info to do this.

The problem example is:

-- first, the dictionary list of "You may assume that all known words provided are unique.":
40 abc
41 bca
42 dac
43 dbc
44 cba

-- now, the "recieved" and garbled unknown words:
45 (ab)(bc)(ca)
46 abc
47 (abc)(abc)(abc)
48 (zyx)bc
49

-- now the supposedly true results? :
50 Output
51 Case #1: 2 -- cannot be true, could also match several others
52 Case #2: 1 -- obviously, it's in the dictionary of known words
53 Case #3: 3 -- could match any known, and many unknown words
54 Case #4: 0 -- obviously true, no z, y, or x


So something is wrong somewhere. I mean besides needing to use the double backslashes to get newlines, and the 4 dashes in some places to get the 2-dash Eu comment format.

useless

_{edit by Derek to demonstrate alternative creoles tag so Kat doesn't have to use forced-line breaks etc ...}

5. Re: Fun Test Problem

• Posted by DerekParnell (admin) May 22, 2010
• 1718 views

Using Euphoria 4 syntax ...

include std/io.e 
include std/text.e 
include std/sequence.e 
include std/convert.e 
 
/* ** Get control data ** 

   This is one line containing three integers: 
      #1 = Maximum length of a word 
      #2 = Number of words in dictionary 
      #3 = Number of test cases in sample. 
*/ 
 
sequence dict = {} 
integer dictsize = 0 
 
integer inpf = open("input.txt", "r") 
if inpf = -1 then 
	puts(1, "Unable to open input.txt\n") 
	abort(0) 
end if 
 
integer outf = open("output.txt", "w") 
if outf = -1 then 
	puts(1, "Unable to open output.txt\n") 
	abort(0) 
end if 
 
object aLine 
 
aLine = gets(inpf) 
if atom(aLine) then 
	puts(1, "!! No data in input file\n") 
	abort(1) 
end if 
 
aLine = split(trim(aLine)) 
if length(aLine) != 3 then 
	puts(1, ` 

____ 
	!! Control data format error. 
	Expecting first line to contain exactly three integers 
	`) 

	abort(1) 
end if 
 
integer max_word_size = to_integer(aLine[1]) 
integer max_dict_size = to_integer(aLine[2]) 
integer max_test_size = to_integer(aLine[3]) 
 
for i = 1 to max_dict_size do 
	aLine = gets(inpf) 
	if atom(aLine) then 
		puts(1, "!!Expected more dictionary entries.\n") 
		abort(1) 
	end if 
	dict = append(dict, trim(aLine)) 
end for 
 
integer this_case = 0 
integer index 
integer state 
sequence pattern 
 
for i = 1 to max_test_size do 
	aLine = gets(inpf) 
	if atom(aLine) then 
		puts(1, "!!Expected more test entries.\n") 
		abort(1) 
	end if 
	 
	aLine = trim(aLine) 
	this_case += 1 
	pattern = {} 
	index = 1 
	state = 0 
	while index <= length(aLine) do 
		switch aLine[index] do 
			case '(' then 
				if state = 0 then 
					state = 1 
					pattern = append(pattern, {}) 
				else 
					printf(1, "%s\n", {aLine}) 
					printf(1, "!!Not expecting '(' at column %d\n", index) 
					abort(1) 
				end if 
				 
			case ')' then 
				if state = 1 then 
					state = 0 
				else 
					printf(1, "%s\n", {aLine}) 
					printf(1, "!!Not expecting ')' at column %d\n", index) 
					abort(1) 
				end if 
				 
			case else 
				if state = 0 then 
					pattern = append(pattern, {aLine[index]}) 
				else 
					pattern[$] &= aLine[index] 
				end if 
		end switch 
		index += 1 
	end while 
	 
	if state != 0 then 
		printf(1, "%s\n", {aLine}) 
		puts(1, "!!Missing ')'\n") 
		abort(1) 
	end if 
 
	-- At this point, we have a pattern set up, 
	-- so we check each word in the dictionary against the pattern.	 
	integer case_count = 0 
	for j = 1 to length(dict) label "dict_scan" do 
		sequence this_word = dict[j] 
		if length(this_word) != length(pattern) then 
			continue 
		end if 
		 
		for k = 1 to length(this_word) do 
			if find(this_word[k], pattern[k]) = 0 then 
				continue "dict_scan" 
			end if 
		end for 
	 
		case_count += 1 
		 
	end for 
	 
	printf(outf, "Case #%d:%d\n", {i, case_count}) 
end for 
 
close(inpf) 
close(outf) 
-- end of code -- 
 

7. Re: Fun Test Problem

• Posted by DerekParnell (admin) May 22, 2010
• 1703 views

Kat, I think you are missing an important point in the problem description. The input to the program will always contain the entire dictionary of known words.

So in the example given the we know that there are only five known words in total. The patterns given are to be matched against only those five words, and thus all other possible words are to be ignored.

Thanks Kat. I did know that and I thought the best way of explaining this tag would be to demonstrate its usage. There are also many other capabilities of Creole that are not mentioned in the "More Common Formatting" docs. I've asked, long ago, for a link to be placed in this area to a wiki page that would explain the full Creole usage.

9. Re: Fun Test Problem

• Posted by useless May 22, 2010
• 1704 views

Actually, the point i was missing was: "where X is the test case number, starting from 1, and K indicates how many words in the alien language match the pattern.", not which words are matched.

David Cuny got me started on a spell checker years ago, and i think the only thing it doesn't do is count how many possible matches there are, tho it does everything else.

useless

11. Re: Fun Test Problem

• Posted by evanmars May 26, 2010
• 1597 views

Someday, I'll get around to downloading v4 and play with it. I haven't had much time for Euphoria programming lately, but I had some down time at work, saw this post while lurking, noticed nobody had attempted it, and thought I'd give it a try.