OpenEuphoria

1. Directory info?

• Posted by DonCCole Sep 18, 2008
• 1117 views

Hello Everybody,

How can I total number of bytes in a directory or drive?

And Bytes free?

Don Cole A Bug is an un-documentedfeature. A Feature is a documented Bug.

3. Re: Directory info?

• Posted by DanM Sep 20, 2008
• 1124 views

Don,

There's a demo with Win32Lib called "WalkDir", which might be overkill for what you want, but it should be adaptable to output file/directory sizes for summing; right now it just shows all dirs/files, but you could certainly tweak it for file sizes. I think I did something like that to show all dirs ranked by size on a drive, but I'm not sure where it is right now.

DanM

5. Re: Directory info?

• Posted by DanM Sep 20, 2008
• 1088 views
• Last edited Sep 21, 2008

I don't know if this will work or not, but given that the dos/command prompt will allow dir to get what you want, maybe you could use system() or system_exec() with the dir command to retrieve the dir info & then parse it for the parts you need?

Dan

7. Re: Directory info?

• Posted by euphoric (admin) Sep 21, 2008
• 1051 views

In your program do

   system( "dir > myfile.txt", 2 ) 

Here's a sample of what you'll get in myfile.txt:

C:\Documents and Settings\HP_Administrator>dir 
 Volume in drive C is HP_PAVLON 
 Volume Serial Number is CD14-1DE0 
 
 Directory of C:\Documents and Settings\HP_Administrator 
 
09/20/2008  12:34 AM    <DIR>          . 
09/20/2008  12:34 AM    <DIR>          .. 
09/20/2008  10:27 PM    <DIR>          Desktop 
06/08/2008  09:28 PM               199 ex.err 
03/01/2008  08:21 PM    <DIR>          Favorites 
09/02/2008  05:45 PM    <DIR>          My Documents 
03/01/2008  06:50 PM    <DIR>          Start Menu 
03/08/2008  06:54 PM    <DIR>          Temp 
05/25/2006  04:56 PM    <DIR>          WINDOWS 
               2 File(s)         60,943 bytes 
              11 Dir(s)  182,539,636,736 bytes free 

9. Re: Directory info?

• Posted by just_me Sep 21, 2008
• 1078 views

Again:

On Windows:

include machine.e 
include dll.e 
include get.e 
 
 
constant 
	SECTORS_PER_CLUSTER 	 = 1, 
	BYTES_PER_SECTOR		 = 2, 
	NUMBER_OF_FREE_CLUSTERS  = 3, 
	TOTAL_NUMBER_OF_CLUSTERS = 4, 
 
	TOTAL	  = 1, 
	USED	  = 2, 
	AVAILABLE = 3, 
 
	KERNEL32 = open_dll("kernel32.dll"), 
 
	xGetDiskFreeSpaceA = define_c_func(KERNEL32, "GetDiskFreeSpaceA", {C_CHAR, C_POINTER, C_POINTER, C_POINTER, C_POINTER}, C_INT)	 
 
 
sequence sDiskSpace 
integer void 
 
function GetDiskFreeSpaceA(object xPath) 
	sequence sDiskSpace 
	atom aPath 
	atom aSectorsPerCluster, aBytesPerSector, aNumberOfFreeClusters, aTotalNumberOfClusters 
 
	sDiskSpace = {0, 0, 0, 0} 
 
	if sequence(xPath) then 
		aPath = allocate_string(xPath) 
	else 
		aPath = NULL 
	end if 
 
	aSectorsPerCluster = allocate(4) 
	aBytesPerSector = allocate(4) 
	aNumberOfFreeClusters = allocate(4) 
	aTotalNumberOfClusters = allocate(4) 
 
 
	if c_func(xGetDiskFreeSpaceA, {aPath, aSectorsPerCluster, aBytesPerSector, aNumberOfFreeClusters, aTotalNumberOfClusters}) then 
		sDiskSpace[SECTORS_PER_CLUSTER] = peek4s(aSectorsPerCluster) 
		sDiskSpace[BYTES_PER_SECTOR] = peek4s(aBytesPerSector) 
		sDiskSpace[NUMBER_OF_FREE_CLUSTERS] = peek4s(aNumberOfFreeClusters) 
		sDiskSpace[TOTAL_NUMBER_OF_CLUSTERS] = peek4s(aTotalNumberOfClusters) 
	end if 
 
	if sequence(xPath) then 
		free(aPath) 
	end if 
	free(aSectorsPerCluster) 
	free(aBytesPerSector) 
	free(aNumberOfFreeClusters) 
	free(aTotalNumberOfClusters) 
 
	return sDiskSpace 
end function 
 
function GetDiskSpaceInBytes(object xPath) 
	sequence sBytes, sTmpBytes 
	sBytes = {0, 0, 0} 
	sTmpBytes = GetDiskFreeSpaceA(xPath) 
	sBytes[TOTAL] = sTmpBytes[BYTES_PER_SECTOR] * sTmpBytes[SECTORS_PER_CLUSTER] * sTmpBytes[TOTAL_NUMBER_OF_CLUSTERS] 
	sBytes[AVAILABLE] = sTmpBytes[BYTES_PER_SECTOR] * sTmpBytes[SECTORS_PER_CLUSTER] * sTmpBytes[NUMBER_OF_FREE_CLUSTERS] 
	sBytes[USED] = sBytes[TOTAL] - sBytes[AVAILABLE] 
	return sBytes 
end function 
 
sDiskSpace = GetDiskSpaceInBytes("C:") 
 
printf(1, "Total: %d\nUsed: %d\nAvailable: %d", {sDiskSpace[TOTAL], sDiskSpace[USED], sDiskSpace[AVAILABLE]}) 
 
 
void = wait_key() 

JG

11. Re: Directory info?

• Posted by ne1uno Sep 21, 2008
• 1068 views

GetDiskFreeSpace has a problem with disks bigger than 2gig, I modified your program to use GetDiskFreeSpaceEx
not really tested that well and output needs work to divide by 1024 or 1000 to get Gig's or Megs

--GetDiskFreeSpace 
--using the as yet unreleased eu4 
 
include std/machine.e  
include std/dll.e  
include std/get.e 
include std/console.e 
 
include std/text.e 
include "std/sequence.e" 
 
constant FREEBYTESAVAILABLETOCALLER = 1 
      , TOTALNUMBEROFBYTES  = 2 
      , TOTALNUMBEROFFREEBYTES  = 3 
 
 ,KERNEL32 = open_dll("kernel32.dll") 
 ,xGetDiskFreeSpaceExA = define_c_func(KERNEL32 
    , "GetDiskFreeSpaceExA" 
    , {C_CHAR, C_POINTER, C_POINTER, C_POINTER} 
    , C_INT) 
 
sequence sDiskSpace  
integer void 
 
--~ typedef union _ULARGE_INTEGER {   
    --~ struct { 
        --~ DWORD LowPart;  
        --~ DWORD HighPart;  
    --~ }; 
    --~ DWORDLONG QuadPart; 
--~ } ULARGE_INTEGER;  
 
 
 
public function comafy(object n, sequence mode="%f", object sep=",") 
    --could get seperator from locale? 
    --maybe should allow comafy non numerics? 
    --should allow already spaced or underlined seperated numbers? 
 
    sequence s="" 
    object so 
      
    --assumne it is an atom 
     s = sprintf(mode, n) 
      --reverse & chunk it don't add extra coma if <3 digits don't count decimal point 
      --don't get confused if locale is not using decimal point or coma 
    so= split(s, '.') 
      s = reverse(join(chunk(reverse(so[1]), 3), sep) )  
       if length(so)>1 then s &=  "." & so[2] end if 
    return s 
end function 
 
 
function GetDiskFreeSpaceExA(object xPath) 
    sequence sDiskSpace  
    atom aPath  
    atom aFreeBytesAvailableToCaller 
        , aTotalNumberOfBytes 
        , aTotalNumberOfFreeBytes 
     
    sDiskSpace = {0, 0, 0, 0} 
     
    if sequence(xPath) then aPath = allocate_string(xPath) 
    else aPath = NULL  
    end if 
     
    aFreeBytesAvailableToCaller = allocate(4) 
    aTotalNumberOfBytes = allocate(4) 
    aTotalNumberOfFreeBytes = allocate(4) 
     
    if c_func(xGetDiskFreeSpaceExA 
        , {aPath, aFreeBytesAvailableToCaller 
          , aTotalNumberOfBytes, aTotalNumberOfFreeBytes}) then 
    -- values obtained by this function are of type ULARGE_INTEGER.  
    -- Be careful not to truncate these values to 32 bits. 
     sDiskSpace[FREEBYTESAVAILABLETOCALLER] =  
               peek4s(aFreeBytesAvailableToCaller) +  
                 (#FFFFFFFF * peek4s(aFreeBytesAvailableToCaller+4)) 
     sDiskSpace[TOTALNUMBEROFBYTES] =  
               peek4s(aTotalNumberOfBytes) +   
                 (#FFFFFFFF * peek4s(aTotalNumberOfBytes+4)) 
     sDiskSpace[TOTALNUMBEROFFREEBYTES] =  
               peek4s(aTotalNumberOfFreeBytes) +   
                 (#FFFFFFFF * peek4s(aTotalNumberOfFreeBytes+4)) 
   end if 
     
    if aPath then free(aPath) end if 
     free(aFreeBytesAvailableToCaller) 
     free(aTotalNumberOfBytes) 
     free(aTotalNumberOfFreeBytes) 
     
    return sDiskSpace 
end function 
 
sequence path="C:"  --should check exists 
 
sDiskSpace = GetDiskFreeSpaceExA(path) 
 
printf(1, path &" Total: %s\nUsed: %s\nAvailable: %s\n" 
    , {comafy(sDiskSpace[TOTALNUMBEROFBYTES]) 
      , comafy( 
        sDiskSpace[TOTALNUMBEROFBYTES] - sDiskSpace[TOTALNUMBEROFFREEBYTES] 
        ) 
       , comafy(sDiskSpace[FREEBYTESAVAILABLETOCALLER]) 
       }) 
 
void = wait_key()  
 
 

13. Re: Directory info?

• Posted by DerekParnell (admin) Sep 21, 2008
• 1045 views

That problem only occurs on ancient Windows systems (Win 95/98/ME) which are also unlikely to have large drives.

    aFreeBytesAvailableToCaller = allocate(4) 
    aTotalNumberOfBytes = allocate(4) 
    aTotalNumberOfFreeBytes = allocate(4) 

Should be

    aFreeBytesAvailableToCaller = allocate(8) 
    aTotalNumberOfBytes = allocate(8) 
    aTotalNumberOfFreeBytes = allocate(8) 

15. Re: Directory info?

• Posted by otterdad Sep 22, 2008
• 1071 views

i use a similar version of that code posted by Al Getz in 03

http://www.rapideuphoria.com/getdrivesinfo.zip

17. Re: Directory info?

• Posted by just_me Sep 23, 2008
• 1171 views

Sure. No acknowledgement required.

JG