OpenEuphoria

1. system() help

• Posted by GeorgeWalters Aug 15, 2008
• 1426 views

I'm using system(rmdir.....) in a loop deleting directories but get a black screen flashing each time it executes. Is there another way to loop without flashing the black screen? I would just like it to delete the stuff w/o any screen feedback. How can I do this? thanks for any ideas.

3. Re: system() help

• Posted by GeorgeWalters Aug 15, 2008
• 1448 views

It was the only way I could think of. system_exec would not work with rmdir... but it might with your idea of using start. I"ll try it. thanks

5. Re: system() help

• Posted by jimcbrown (admin) Aug 15, 2008
• 1478 views

If thats because its an internal command, then this may work:

system("start /b cmd /c rmdir /s /q " & targetRoot & str(i), 2)

7. Re: system() help

• Posted by gbonvehi Aug 15, 2008
• 1473 views

Can you use the Win32 API and it's targeting a win NT based platform? If that's the case, you can use RemoveDirectory ( http://msdn.microsoft.com/en-us/library/aa365488.aspx ).

9. Re: system() help

• Posted by jimcbrown (admin) Aug 15, 2008
• 1482 views

May need additional options.

Try "start /b /wait /min cmd /c rmdir ..."

The full list of options to start is at:

http://www.computerhope.com/starthlp.htm

Failing that, you could try run.exe from the cygwin distribution (mingw might have a version as well) which is suppose to be designed to run programs with the console window hidden.

11. Re: system() help

• Posted by ghaberek (admin) Aug 15, 2008
• 1470 views

The solution here SHFileOperation. I noticed it's not in Win32Lib. I'll throw together an example and post it up in a bit.

-Greg

13. Re: system() help

• Posted by gbonvehi Aug 15, 2008
• 1453 views

Well, after some hours at work without work (actually 3 days by now, just changed job :/ ), I crafted this.. :)

include machine.e 
include dll.e 
 
constant wKernel32 = open_dll("kernel32.dll") 
constant wDeleteFile = define_c_func(wKernel32, "DeleteFileA", {C_POINTER},  
C_LONG) 
constant wFindFirstFile = define_c_func(wKernel32, "FindFirstFileA", {C_POINTER,  
C_POINTER}, C_POINTER) 
constant wFindNextFile = define_c_func(wKernel32, "FindNextFileA", {C_POINTER,  
C_POINTER}, C_LONG) 
constant wFindClose = define_c_func(wKernel32, "FindClose", {C_POINTER}, C_LONG) 
constant wRemoveDirectory = define_c_func(wKernel32, "RemoveDirectoryA", {C_POINTER}, C_LONG) 
 
constant wFILE_ATTRIBUTE_DIRECTORY = 16 
constant wINVALID_HANDLE_VALUE = -1 
 
constant sizeOfDWORD = 4 
constant wMAX_PATH = 260 
 
function peek_string(atom addr, atom maxbytes) 
    sequence text 
    atom chr 
    maxbytes += addr 
    text = {} 
    if addr > 0 then 
        chr = peek(addr) 
        while chr != 0 and addr < maxbytes do 
            text = text & chr 
            addr += 1 
            chr = peek(addr) 
        end while 
    end if 
    return text 
end function 
 
function deleteFile(sequence name) 
    atom pname 
    atom ret 
 
    pname = allocate_string(name) 
 
    ret = c_func(wDeleteFile,{pname}) 
     
    free(pname) 
     
    return ret 
end function 
 
--typedef struct _FILETIME { 
--  DWORD dwLowDateTime; 
--  DWORD dwHighDateTime; 
--} FILETIME,  
-- *PFILETIME; 
constant sizeOfFILETIME = sizeOfDWORD * 2 
function allocate_FILETIME() 
    atom pFILETIME 
     
    pFILETIME = allocate(sizeOfFILETIME) 
     
    return pFILETIME 
end function 
 
--typedef struct _WIN32_FIND_DATA { 
--  DWORD dwFileAttributes; 
--  FILETIME ftCreationTime; 
--  FILETIME ftLastAccessTime; 
--  FILETIME ftLastWriteTime; 
--  DWORD nFileSizeHigh; 
--  DWORD nFileSizeLow; 
--  DWORD dwReserved0; 
--  DWORD dwReserved1; 
--  TCHAR cFileName[MAX_PATH]; 
--  TCHAR cAlternateFileName[14]; 
--} WIN32_FIND_DATA,  
-- *PWIN32_FIND_DATA,  
-- *LPWIN32_FIND_DATA; 
constant sizeOfWIN32_FIND_DATA = sizeOfDWORD * 7 + sizeOfFILETIME * 3 +  
wMAX_PATH + 14 
constant WIN32_FIND_DATA_dwFileAttributes = 0 
constant WIN32_FIND_DATA_cFileName =  sizeOfFILETIME * 3 + sizeOfDWORD * 5 
function allocate_WIN32_FIND_DATA() 
    atom pWIN32FINDDATA 
     
     
    pWIN32FINDDATA = allocate(sizeOfWIN32_FIND_DATA) 
     
    return pWIN32FINDDATA 
end function 
 
function findFirstFile(sequence file, atom pwin32finddata) 
    atom fHandle, pfile 
    pfile = allocate_string(file) 
     
    fHandle = c_func(wFindFirstFile,{pfile, pwin32finddata}) 
     
    free(pfile) 
    return fHandle 
end function 
 
function findNextFile(atom handle, atom pwin32finddata) 
    return c_func(wFindNextFile,{handle, pwin32finddata}) 
end function 
 
function findClose(atom handle) 
    return c_func(wFindClose, {handle}) 
end function 
 
global function removeDirectory(sequence name) 
    atom fHandle, pwin32finddata, retval, FileAttributes, pname 
    sequence filename, oriname 
 
    retval = 0 
 
    pwin32finddata = allocate_WIN32_FIND_DATA() 
     
    if length(name) then 
        if name[$] != '\\' then 
            name = name & "\\" 
        end if 
        oriname = name 
        name = name & "*" 
 
        fHandle = findFirstFile(name, pwin32finddata) 
        if fHandle != -1 then 
     
            filename = peek_string(pwin32finddata+WIN32_FIND_DATA_cFileName, 259) 
            poke(pwin32finddata+WIN32_FIND_DATA_cFileName,0) 
             
            if not equal(filename,".") and not equal(filename,"..") then 
                FileAttributes = peek4u(pwin32finddata+WIN32_FIND_DATA_dwFileAttributes) 
                FileAttributes = and_bits(FileAttributes, wFILE_ATTRIBUTE_DIRECTORY) 
                if FileAttributes != 0 then 
                    retval = removeDirectory(oriname & filename) 
                else 
                    retval = deleteFile(oriname & filename) 
                end if 
                if not retval then 
                    fHandle = wINVALID_HANDLE_VALUE 
                end if 
            end if 
            if fHandle != wINVALID_HANDLE_VALUE then 
                while findNextFile(fHandle, pwin32finddata) do 
     
                    filename = peek_string(pwin32finddata+WIN32_FIND_DATA_cFileName, 259) 
                    poke(pwin32finddata+WIN32_FIND_DATA_cFileName,0) 
     
                    if not equal(filename,".") and not equal(filename,"..") then 
                        FileAttributes = peek4u(pwin32finddata+WIN32_FIND_DATA_dwFileAttributes) 
                        FileAttributes = and_bits(FileAttributes, wFILE_ATTRIBUTE_DIRECTORY) 
                        if FileAttributes != 0 then 
                            retval = removeDirectory(oriname & filename) 
                        else 
                            retval = deleteFile(oriname & filename) 
                        end if 
                        if not retval then 
                            exit 
                        end if 
                    end if 
                     
                end while 
                if findClose(fHandle) then end if 
            end if 
             
            pname = allocate_string(name[1..$-1]) 
            retval = c_func(wRemoveDirectory,{pname}) 
            free(pname) 
             
        end if 
 
        free(pwin32finddata) 
 
    end if 
    return retval 
end function 

I tested it and worked, I hope it does for you too :)

Little test:

include removedirectory.ew 
 
procedure listFilesTest() 
    sequence test 
    test =  "c:\\temp\\test\\" 
        if removeDirectory(test) then end if 
    while get_key() = -1 do 
    end while 
end procedure 
 
listFilesTest() 

15. Re: system() help

• Posted by gbonvehi Aug 15, 2008
• 1439 views

Wow, nice work Greg, I think he should use that wrapper heh :) Mine actually wraps removeDirectory, but also does a recursive file deletion inside it if it's not empty. I could have used euphoria's dir() routine (in case someone is thinking about that), but well, I was wrapping one thing... and I was tempted by another.. heh

I discovered a little bug in my code (ugly actually forgot to allocate FILETIME), I'll post an updated copy just in case. I also added the open_dll test just to make it prettier :) Oh, also two comment lines with the description of the function.

nclude machine.e 
include dll.e 
 
constant 
    wKernel32 = open_dll("kernel32.dll"), 
    wDeleteFile = define_c_func(wKernel32, "DeleteFileA", {C_POINTER}, C_LONG), 
    wFindFirstFile = define_c_func(wKernel32, "FindFirstFileA", {C_POINTER, C_POINTER}, C_POINTER), 
    wFindNextFile = define_c_func(wKernel32, "FindNextFileA", {C_POINTER, C_POINTER}, C_LONG), 
    wFindClose = define_c_func(wKernel32, "FindClose", {C_POINTER}, C_LONG), 
    wRemoveDirectory = define_c_func(wKernel32, "RemoveDirectoryA", {C_POINTER}, C_LONG), 
    wFILE_ATTRIBUTE_DIRECTORY = 16, 
    wINVALID_HANDLE_VALUE = -1, 
 
    sizeOfDWORD = 4, 
    wMAX_PATH = 260 
 
function peek_string(atom addr, atom maxbytes) 
    sequence text 
    atom chr 
    maxbytes += addr 
    text = {} 
    if addr > 0 then 
        chr = peek(addr) 
        while chr != 0 and addr < maxbytes do 
            text = text & chr 
            addr += 1 
            chr = peek(addr) 
        end while 
    end if 
    return text 
end function 
 
function deleteFile(sequence name) 
    atom pname 
    atom ret 
 
    pname = allocate_string(name) 
 
    ret = c_func(wDeleteFile,{pname}) 
     
    free(pname) 
     
    return ret 
end function 
 
constant 
    sizeOfFILETIME = sizeOfDWORD * 2 
     
function allocate_FILETIME() 
    atom pFILETIME 
     
    pFILETIME = allocate(sizeOfFILETIME) 
     
    return pFILETIME 
end function 
 
constant 
    sizeOfWIN32_FIND_DATA = sizeOfDWORD * 7 + sizeOfFILETIME * 3 + wMAX_PATH + 14, 
    WIN32_FIND_DATA_dwFileAttributes = 0, 
    WIN32_FIND_DATA_ftCreationTime = 4, 
    WIN32_FIND_DATA_ftLastAccessTime = 8, 
    WIN32_FIND_DATA_ftLastWriteTime = 12, 
    WIN32_FIND_DATA_cFileName =  sizeOfFILETIME * 3 + sizeOfDWORD * 5 
     
function allocate_WIN32_FIND_DATA(sequence FILETIMEstructs) 
    atom pWIN32FINDDATA 
    pWIN32FINDDATA = 0 
    if length(FILETIMEstructs) = 3 then 
        for I = 1 to 3 do 
            if FILETIMEstructs[I] = 0 then 
                return 0 
            end if 
        end for 
        pWIN32FINDDATA = allocate(sizeOfWIN32_FIND_DATA) 
        poke(pWIN32FINDDATA+WIN32_FIND_DATA_ftCreationTime,FILETIMEstructs[1]) 
        poke(pWIN32FINDDATA+WIN32_FIND_DATA_ftLastAccessTime,FILETIMEstructs[2]) 
        poke(pWIN32FINDDATA+WIN32_FIND_DATA_ftLastWriteTime,FILETIMEstructs[3]) 
    end if 
    return pWIN32FINDDATA 
end function 
 
function findFirstFile(sequence file, atom pwin32finddata) 
    atom fHandle, pfile 
    pfile = allocate_string(file) 
     
    fHandle = c_func(wFindFirstFile,{pfile, pwin32finddata}) 
     
    free(pfile) 
    return fHandle 
end function 
 
function findNextFile(atom handle, atom pwin32finddata) 
    return c_func(wFindNextFile,{handle, pwin32finddata}) 
end function 
 
function findClose(atom handle) 
    return c_func(wFindClose, {handle}) 
end function 
 
-- It will stop processing on error returning 0 
-- name must be a path 
 
global function removeDirectory(sequence name) 
    atom fHandle, pwin32finddata, retval, FileAttributes, pname 
    sequence filename, oriname, FILETIMEstructs 
 
    retval = 0 
 
    FILETIMEstructs = {allocate_FILETIME(),allocate_FILETIME(),allocate_FILETIME()} 
    pwin32finddata = allocate_WIN32_FIND_DATA(FILETIMEstructs) 
     
    if length(name) and pwin32finddata != 0 then 
        if name[$] != '\\' then 
            name = name & "\\" 
        end if 
        oriname = name 
        name = name & "*" 
 
        fHandle = findFirstFile(name, pwin32finddata) 
        if fHandle != -1 then 
     
            filename = peek_string(pwin32finddata+WIN32_FIND_DATA_cFileName, 259) 
            poke(pwin32finddata+WIN32_FIND_DATA_cFileName,0) 
             
            if not equal(filename,".") and not equal(filename,"..") then 
                 
                FileAttributes = peek4u(pwin32finddata+WIN32_FIND_DATA_dwFileAttributes) 
                FileAttributes = and_bits(FileAttributes, wFILE_ATTRIBUTE_DIRECTORY) 
                if FileAttributes != 0 then 
                    retval = removeDirectory(oriname & filename) 
                else 
                    retval = deleteFile(oriname & filename) 
                end if 
                 
                if not retval then 
                    fHandle = wINVALID_HANDLE_VALUE 
                end if 
            end if 
            if fHandle != wINVALID_HANDLE_VALUE then 
                while findNextFile(fHandle, pwin32finddata) do 
     
                    filename = peek_string(pwin32finddata+WIN32_FIND_DATA_cFileName, 259) 
                    poke(pwin32finddata+WIN32_FIND_DATA_cFileName,0) 
     
                    if not equal(filename,".") and not equal(filename,"..") then 
                         
                        FileAttributes = peek4u(pwin32finddata+WIN32_FIND_DATA_dwFileAttributes) 
                        FileAttributes = and_bits(FileAttributes, wFILE_ATTRIBUTE_DIRECTORY) 
                        if FileAttributes != 0 then 
                            retval = removeDirectory(oriname & filename) 
                        else 
                            retval = deleteFile(oriname & filename) 
                        end if 
                         
                        if not retval then 
                            exit 
                        end if 
                    end if 
                     
                end while 
                if findClose(fHandle) then end if 
            end if 
             
            pname = allocate_string(name[1..$-1]) 
            retval = c_func(wRemoveDirectory,{pname}) 
            free(pname) 
             
        end if 
 
        for I = 1 to length(FILETIMEstructs) do 
            free(FILETIMEstructs[1])         
        end for 
        free(pwin32finddata) 
 
    end if 
    return retval 
end function 
 
if wKernel32 = 0 then 
    puts(1,"Error on open_dll(\"kernel32.dll\")") 
    abort(1) 
end if 
 

17. Re: system() help

• Posted by jeremy (admin) Aug 15, 2008
• 1468 views

I hate to say this, but maybe you need it for 3.x, but 4.0 standard library has the functions:

• file_exists
• copy_file
• rename_file
• delete_file
• move_file
• create_directory
• remove_directory
• clear_directory -- remove dir recursively

You can look at how they are implemented via the URL:

http://rapideuphoria.svn.sourceforge.net/svnroot/rapideuphoria/trunk/include/std/filesys.e

Jeremy

19. Re: system() help

• Posted by gbonvehi Aug 15, 2008
• 1469 views

I'm glad to hear that :) The only problem with remove_directory (WIN32) there, is that it just calls remove directory API function which doesn't delete a directory if it's not empty.

Even cooler :)

21. Re: system() help

• Posted by gbonvehi Aug 15, 2008
• 1464 views

I swear I didn't see that function when I replied :/ Great to see it already done! So, now, instead of Greg's wrapper or mine, he can convert that code and it's done :)

23. Re: system() help

• Posted by CChris Aug 16, 2008
• 1447 views

Why do you use a DOS command to delete a file under Windows? Any use of DOS willl spawn a console window.

CChris

25. Re: system() help

• Posted by GeorgeWalters Aug 17, 2008
• 1427 views

Thanks, but I'm stuck in 2.3 and have not needed to upgrade it till now.