OpenEuphoria

2. Re: RosettaCode

• Posted by bruce1961 Jan 26, 2011
• 2117 views

Nice to see some folk have taken up the challenge.

Is it fair enough to assume that Function Composition is impossible in Euphoria?

Kind regards, Bruce.

4. Re: RosettaCode

• Posted by bruce1961 Jan 26, 2011
• 2014 views

function compose( integer f, integer g, object x ) 
    return call_func( f, {call_func( g, {x} )} ) 
end function 

Wow. Way cool, that.

6. Re: RosettaCode

• Posted by mattlewis (admin) Jan 26, 2011
• 1994 views

sin is a built-in, and you cannot get a routine_id for a built-in. That said, you still shouldn't get a machine exception when using an invalid routine_id. That looks like a bug in the interpreter.

Matt

8. Re: RosettaCode

• Posted by bruce1961 Jan 26, 2011
• 1984 views

include std/math.e 
 
function sine( object x ) 
	return sin(x) 
end function 
 
function compose( integer f, integer g, object x )  
    return call_func( f, {call_func( g, {x} )} )  
end function  
 
integer iSine = routine_id("sine") 
integer iArcSin = routine_id("math:arcsin") 
? iSine 
? iArcSin 
object func = compose( iSine, iArcSin, 0.5 ) 
? func 

That seems to work better, giving '0' and '1' for the routine_ids.

Bruce.

10. Re: RosettaCode

• Posted by cargoan Jan 26, 2011
• 1961 views

Also:

include std/math.e  
  
function sin( object x )  
    return eu:sin(x)  
end function  
 
function compose( integer f, integer g, object x )   
    return call_func( f, {call_func( g, {x} )} )   
end function   
  
integer iSin = routine_id("sin")  
integer iArcSin = routine_id("arcsin")  
? iSin  
? iArcSin  
object func = compose( iSin, iArcSin, 0.5 )  
? func  

carlos@carlos-HP-s3733es:~/Escritorio$ eui compose.ex 
0 
1 
0.5 
 

12. Re: RosettaCode

• Posted by mattlewis (admin) Jan 26, 2011
• 2002 views

function compose( integer f, integer g, object x ) 
    return call_func( f, {call_func( g, {x} )} ) 
end function 

Yeah, I suppose not. With a little more work:

sequence compositions = {} 
function compose( sequence ids ) 
    compositions = append( compositions, ids ) 
    return length( compositions ) 
end function 
 
function call_composition( integer c, sequence x ) 
    sequence comp = compositions[c] 
    for i = length( comp ) to 1 by -1 do 
        x = call_func( comp[i], x ) 
    end for 
    return x 
end function 
 
... 
 
fg = compose( f, g ) 
call_composition( fg, {1} ) 

Matt

14. Re: RosettaCode

• Posted by jimcbrown (admin) Jan 26, 2011
• 1953 views

sequence compositions = {} 
function compose( sequence ids ) 
    compositions = append( compositions, ids ) 
    return length( compositions ) 
end function 
 
function call_composition( integer c, sequence x ) 
    sequence comp = compositions[c] 
    for i = length( comp ) to 1 by -1 do 
        x = call_func( comp[i], x ) 
    end for 
    return x 
end function 
 
... 
 
fg = compose( {f, g} ) -- edited to use {} 
call_composition( fg, {1} ) 

But any singular routine-id can be turned into a compose-id.

We can extend this further so it allows composing with routine-ids, compose-ids, or any combination of compose-ids and routine-ids like so:

-- eat up the first element so compose-id -1 is never valid 
sequence compositions = {-1} 
function compose( sequence ids ) 
    compositions = append( compositions, ids ) 
    return -length( compositions ) 
end function 
 
function call_composition( integer c, sequence x ) 
    sequence comp = compositions[-c] 
    for i = length( comp ) to 1 by -1 do 
	if comp[i] = -1 then 
		-- error ? 
	elsif comp[i] < 0 then 
        	x = call_composition( comp[i], x ) 
	else 
        	x = call_func( comp[i], x ) 
	end if 
    end for 
    return x 
end function 
 
... 
 
fg = compose( {f, g} ) 
hfg = compose( {h, fg} ) 
call_composition( hfg, {1} ) 

It's not possible to turn the resulting compose-id into a routine-id (as far as I know). However, it is possible to create a c-func-id from a compose-id that can be used with c_func().

16. Re: RosettaCode

• Posted by PeteE Jan 26, 2011
• 1931 views

This is what is preventing me from accepting this composition solution. The compose function must take two routine-ids as input, and produce one routine-id as output.*

This I would very much like to see.

-- wrap the built-in call_func function 
function old_call_func(integer id, sequence args) 
  return call_func(id, args) 
end function 
 
-- override built-in call_func to accept an object as the routine-id 
global function call_func(object id, sequence args={}) 
  if sequence(id) then 
    for i = length(id) to 1 by -1 do 
      args = { call_func(id[i], args) } 
    end for 
    return args[1] 
  end if 
  return old_call_func(id, args) 
end function 
 
-- compose two routine-ids into a sequence that can be used with the above call_func 
global function compose(object f, object g) 
  return {f,g} 
end function 

The overriding call_func function here would need to be defined before including any libraries you would want to call with composed routine-ids.

18. Re: RosettaCode

• Posted by mattlewis (admin) Jan 26, 2011
• 1930 views

In 4.0, you can do the override, etc, like this:

 
-- override built-in call_func to accept an object as the routine-id 
override function call_func(object id, sequence args={}) 
  if sequence(id) then 
    for i = length(id) to 1 by -1 do 
      args = { call_func(id[i], args) } 
    end for 
    return args[1] 
  end if 
  return eu:call_func(id, args) -- specify the real built-in 
end function 
 

There's no need for the old_* routine, as you can use the built-in "eu" namespace.

Matt

20. Re: RosettaCode

• Posted by jimcbrown (admin) Jan 26, 2011
• 1891 views

Why does it have to be routine-ids, and not some other token like a c-func-id ?

Ok, ok, it can't be done in Euphoria. At least not Euphoria alone. A bottle of machine code glue is required...

Change the call_func()s in composed_call_back() to call_composition() and pass in compose-ids from the other compose into this compose() and it all works.

To turn only a single routine-id (or compose-id) into a c-func-id, pass NOT_USED as the second id.

include std/dll.e 
include std/machine.e 
 
constant mach = 
{ 
-- 0 
#55, 
-- 1 
#89, #e5, 
-- 3 
#83, #ec, #18, 
-- 6 
#c7, #45, #f4, 
-- 9 
#78, #56, #34, #12, 
-- 13 
#c7, #45, #f8, 
-- 16 
#21, #43, #65, #87, 
-- 20 
#c7, #45, #fc, 
-- 23 
#01, #f0, #01, #f0, 
-- 27 
#83, #ec, #04, 
-- 30 
#ff, #75, #08, 
-- 33 
#ff, #75, #f8, 
-- 36 
#ff, #75, #f4, 
-- 39 
#8b, #45, #fc, 
-- 42 
#ff, #d0, 
-- 44 
#83, #c4, #10, 
-- 47 
#c9, 
-- 48 
#c3 
-- 49 
} 
 
function composed_call_back(integer a, integer b, integer c) 
	return call_func(a, {call_func(b, {c})}) 
end function 
constant composed_call_back_mach = call_back(routine_id("composed_call_back")) 
 
public function compose(integer rid_a, integer rid_b) 
	atom a 
	a = allocate(length(mach)) 
	poke(a, mach) 
	poke4(a + 9, rid_a) 
	poke4(a + 16, rid_b) 
	poke4(a + 23, composed_call_back_mach) 
	return define_c_func("", a, {C_ULONG}, C_ULONG) 
end function 
 
public function identity(object x) 
	return x 
end function 
public constant NOT_USED = routine_id("identity") 
 
-- example code 
function ax(integer i) 
return i + 2 
end function 
 
function bx(integer i) 
return i * 2 
end function 
 
atom zx = compose(routine_id("ax"), routine_id("bx")) 
atom xz = compose(routine_id("bx"), routine_id("ax")) 
 
-- should print 4 
? c_func(zx, {1}) 
 
-- should print 6 
? c_func(xz, {1}) 

22. Re: RosettaCode

• Posted by PeteE Jan 26, 2011
• 1916 views

Because you should be able to use a composed function with library routines such as filter, transform, and apply, or any place that accepts routine-ids. Function composition loses its power if you have to rewrite any called library functions to use call_composition or c_func.

Cool. Thanks.

24. Re: RosettaCode

• Posted by Insolor Aug 23, 2011
• 1664 views

Could someone update the information about Euphoria on this page please?

http://rosettacode.org/wiki/Category:Euphoria

I would do it myself if I knew English better:)