OpenEuphoria

1. countdown display code

• Posted by Senator Aug 16, 2020
• 1505 views

The following code displays a countdown intended to update every second. Most often the seconds display a decrement of 2 seconds, sometimes a 1 second decrement is displayed.

Is there an error in my code?

-- 
-- count_down.ex 
-- 
include std/datetime.e 
include std/math.e 
include std/graphics.e 
include std/os.e 
 
function DaysBetweenDates(datetime dt1,datetime dt2) 
atom d,h,m,s=diff(dt1,dt2) 
d=s/86400 
    h=frac(d)*24 -- hours.xxx 
    d=trunc(d)   -- days 
        m=frac(h)*60    -- minutes.xxx 
        h=trunc(h)      -- hours 
            s=frac(m)*60   -- seconds.xxx 
            m=trunc(m)     -- minutes 
                s=trunc(s)    -- seconds 
return {d,h,m,s} 
end function 
 
public procedure now_until(datetime dt2={2020,9,1,0,0,0}) 
sequence bal, pos = get_position() 
loop do 
    text_color(BRIGHT_WHITE) 
    position(pos[1],pos[2]) puts(1,"            ") position(pos[1],pos[2]) 
    text_color(BLUE) 
    bal=DaysBetweenDates(now(),dt2) 
    printf(1,"%d-%d:%d:%d",{bal[1],bal[2],bal[3],bal[4]}) 
    sleep(1) 
    until equal(bal,dt2)      
end loop 
end procedure 
 
 
now_until() 

Thanks, Ken

3. Re: countdown display code

• Posted by irv Aug 16, 2020
• 1490 views

Here's a version that avoids nasty floating point math:

 
include std/os.e 
include std/console.e 
include std/datetime.e 
 
public procedure now_until(datetime dt={2021,12,25,12,0,0}) 
object dt1 -- (computer time and date) 
object dt2 = to_unix(dt)  
object target = datetime:format(dt,"%A, %b %d, %Y %l:%M:%S %p") 
object diff -- in seconds   
integer sec_now = 0, sec_prev = 0 
loop do  
    dt1 = to_unix(datetime:now()) 
    diff = dt2-dt1 
    diff = from_unix(diff)  
    diff -= {1970,1,1,0,0,0} -- adj for unix EPOCH 
    sec_now = diff[6] 
    if sec_now != sec_prev then 
        display("Time remaining: [b]-[b]-[b] []:[]:[]",diff,0) 
        display(" until []",{target}) 
        sec_prev = diff[6] 
    end if 
    sleep(.1) -- note: must check more than once per second, or time will "jitter" 
    until equal(dt1,dt2)    
end loop  
end procedure  
  
now_until()  
 

Now you know how much time you have to buy me a Christmas gift for next year:

Time remaining: 1-4-10 19:37:9 until Saturday, Dec 25, 2021 12:00:00 AM 
Time remaining: 1-4-10 19:37:8 until Saturday, Dec 25, 2021 12:00:00 AM 
Time remaining: 1-4-10 19:37:7 until Saturday, Dec 25, 2021 12:00:00 AM 

5. Re: countdown display code

• Posted by Senator Aug 17, 2020
• 1420 views

I revised Irv's 1st revision using round instead of trunc, display instead of printf and sleep(.1) instead of sleep(1) per his sample code.. works like charm.

Thanks, again,

function DaysBetweenDates(datetime dt1,datetime dt2)   
atom h,m,s=diff(dt1,dt2), 
d=s/86400     -- days.xx   
    h=frac(d)*24 -- hours.xxx   
    d=round(d,1) -- days 
        m=frac(h)*60      -- minutes.xxx   
        h=round(h,1)      -- hours   
            s=frac(m)*60     -- seconds.xxx   
            m=round(m,1)     -- minutes  
               s=round(s,1)     -- seconds  
return {d,h,m,s}   
end function   
   
public procedure now_until(datetime dt2={2021,1,20,0,0,0})   
sequence bal, pos = get_position()   
object prevbal = 0  
loop do 
    text_color(BRIGHT_WHITE)  
    position(pos[1],pos[2])  
    puts(1,"              ")     
    position(pos[1],pos[2])  
    text_color(BLUE) 
    bal=DaysBetweenDates(now(),dt2)  
    display("[]-[]:[]:[] ",bal,0)  
    sleep(.1)  
    until equal(bal,dt2)     
end loop   
end procedure   
   
now_until()   
 
-- 155-3:4:27